3. グラデーション

第1章でGLSLシェーダーテスターを起動すると、画面いっぱいのグラデーションが表示されました。
此の章では、其のグラデーションを作っているシェーダーを1行ずつ分解し、頂点が4つしか無いのに何故全てのピクセルに違う色が付くのかを理解します。
其の後、色を増やし、色の値をシェーダーに移動し、C側から色をアニメーションさせ、最後に斜め・円形・smoothstepのグラデーションを作ります。

グラデーションは地味に見えますが、空、霧、UI、体力ゲージ、画面のフェード等、ゲームの至る所で使われています。
そして此の章で学ぶ「補間」は、後の章のライティングやテクスチャの土台になります。

第1章でダウンロードしたプロジェクトには、既に此の章の最終結果(3色のアニメーション)が入っています(macOS用のfragment.mac.glslだけはまだ2色の版なので、Macでは2色のグラデーションが表示されます。3.3節で3色にします)。此の章では其処に至るまでの手順を一歩ずつ辿ります。自分で手を動かしたい場合は、先ずfragment.glslとmain.cのユニフォームの行を3.1節の2色の版に戻してから始めて下さい。

3.1 シェーダーの分解

既にあるコードを見てみましょう。
テスターは2つのシェーダーを使います。
頂点毎に1回実行される頂点シェーダー(vertex.glsl)と、ピクセル毎に1回実行されるフラグメントシェーダー(fragment.glsl)です。
macOSでは代わりにvertex.mac.glslとfragment.mac.glslが読み込まれます。中身は同じで、1行目が#version 410 coreになっているだけです。

vertex.glsl

#version 450 core

layout(location = 0) in vec2 aPosition;
layout(location = 1) in vec2 aUv;
out vec2 vUv;

void main() {
  vUv = aUv;
  gl_Position = vec4(aPosition, 0.0, 1.0);
}

分解してみると、先ず最初に #version 450 core があります。
シェーダーがGLSLバージョン4.50のコアプロファイルを使用する事を指定しています。
コアプロファイルでは非推奨の古い機能(gl_FragColor等)は使えませんが、其の分ドライバーは互換性の為の余計な処理をしなくて済みます。
此の行は必ずファイルの一番最初に書かなければなりません。

layout(location = 0) in vec2 aPosition;
layout(location = 1) in vec2 aUv;

此れらの行は、Cコードで提供する頂点シェーダーの入力属性を定義します。
Cコードでは、1つの頂点を4つのfloat(位置のx、y、UVのu、v)で表しています:

  // 頂点データ(フルスクリーンクアッド)を設定
  float vertices[] = {
    -1.0f, -1.0f, 0.0f, 0.0f, // 左下(位置、UV)
     1.0f, -1.0f, 1.0f, 0.0f, // 右下
     1.0f,  1.0f, 1.0f, 1.0f, // 右上
    -1.0f,  1.0f, 0.0f, 1.0f  // 左上
  };
  GLuint indices[] = { 0, 1, 2, 2, 3, 0 };
  ...
  // 頂点属性:位置(location 0)、UV(location 1)
  glVertexAttribPointer(0, 2, GL_FLOAT, GL_FALSE, 4 * sizeof(float), (void *)0);
  glEnableVertexAttribArray(0);
  size_t offset = 2 * sizeof(float);
  glVertexAttribPointer(1, 2, GL_FLOAT, GL_FALSE, 4 * sizeof(float), (void *)offset);
  glEnableVertexAttribArray(1);

layout(location = 0) 及び layout(location = 1) の部分は、頂点属性のバインディング位置を明示的に割り当てます。
glVertexAttribPointerの最初の引数が其の番号です。
2次元ベクトル(vec2)のaPositionは位置0に割り当てられ、X及びY座標での頂点の位置を表します。
位置1には、テクスチャ座標(U及びV)を表すもう一つの2次元ベクトルaUvを割り当てます。
glVertexAttribPointerの残りの引数は「2個のfloat」「正規化しない」「1頂点は4 * sizeof(float)バイト毎に並んでいる」「此の属性は頂点の先頭から何バイト目に有るか」という意味です。
最後に、in キーワードは、此れらが頂点バッファからシェーダーに渡される入力変数である事を示します。

四角形は2つの三角形(インデックス0, 1, 2と2, 3, 0)で出来ています。
UVは左下が(0,0)、右上が(1,1)になる様に置かれている事に注目して下さい。

out vec2 vUv;

此れは出力(out)変数 vUv を vec2 型で宣言し、パイプラインの次のステージ(此の場合はフラグメントシェーダー)に渡されます。
フラグメントシェーダー側では、同じ名前と同じ型のin変数で受け取ります。

void main() {
  vUv = aUv;
  gl_Position = vec4(aPosition, 0.0, 1.0);
}

此れはメイン関数であり、頂点シェーダーのエントリーポイントで、各頂点毎に実行されます。
vUv = aUv; は入力テクスチャ座標 aUv を出力変数 vUv にコピーします。
此の値は次の節で説明する「補間」を経て、フラグメントシェーダーに届きます。

gl_Position = vec4(aPosition, 0.0, 1.0); はビルトイン変数 gl_Position を設定し、クリップ空間での頂点の最終位置を決定します。
aPosition は vec2 なので、X及びY値しかありません。従って z = 0.0 と w = 1.0 を追加します。
w=1なので、此の位置はそのまま正規化デバイス座標(NDC、x及びyが−1〜1の範囲)になり、−1〜1の四角形は画面全体を覆います。

fragment.glsl

最初の状態(2色)のフラグメントシェーダーは次の通りです:

#version 450 core

in vec2 vUv;
out vec4 out_color;

uniform vec3 uColorA;
uniform vec3 uColorB;

void main() {
  vec3 blendedColor = mix(uColorA, uColorB, vUv.x);
  out_color = vec4(blendedColor, 1.0);
}

前述の通り、頂点シェーダーはフラグメントシェーダーにデータを渡します。
従って、今回は in vec2 vUv; が頂点シェーダーから入力されます。
又、out vec4 out_color; があり、此れは4次元ベクトル(vec4)型の出力変数で、最終的なカラー(RGBA)を保持します。
此の値はフレームバッファに書き込まれます。
フラグメントシェーダーにout変数が1つしか無い場合、其れは自動的に0番の出力(画面)になります。

uniform vec3 uColorA;
uniform vec3 uColorB;

此れら2つはユニフォーム変数で、其々3次元ベクトル(vec3)型であり、RGBカラーを表します。
ユニフォームはCコードで設定されるグローバル変数で、1回の描画呼び出しの間、全ての頂点及びフラグメントで同じ値です。
main.cでは、描画の直前に次の2行で値を設定しています:

    glUniform3f(glGetUniformLocation(shaderProgram, "uColorA"), 1.0f, 0.0f, 0.0f); // 赤
    glUniform3f(glGetUniformLocation(shaderProgram, "uColorB"), 0.0f, 1.0f, 0.0f); // 緑

glGetUniformLocationはシェーダーの中の変数名から番号(ロケーション)を探し、glUniform3fは其の番号に3つのfloatを書き込みます。
glUniform*は現在glUseProgramで使っているプログラムに対して働くので、必ずglUseProgramの後に呼びます。

void main() {
  vec3 blendedColor = mix(uColorA, uColorB, vUv.x);
  out_color = vec4(blendedColor, 1.0);
}

此のメイン関数は、レンダリングされるプリミティブの各フラグメント(ピクセル)に対して実行されます。
vec3 blendedColor = mix(uColorA, uColorB, vUv.x); は mix 関数を使用して uColorA と uColorB の間を線型補間します。
補間係数は vUv.x で、UV座標のx成分(画面の左端で0、右端で1)です。

mix(a, b, t) は以下を計算します:

mix(𝐚,𝐛,t)=𝐚(1−t)+𝐛t=𝐚+t(𝐛−𝐚)

此れは線型代数シリーズの第2章で見た線型補間(lerp)と全く同じ物です。
GLSLではlerpではなくmixと言う名前になっているだけです。
vec3に使うと、R、G、Bの其々に同じ式が成分毎に適用されます。

vUv.x = 0 の場合、blendedColor = uColorA になります。
vUv.x = 1 の場合、blendedColor = uColorB になります。
其の間の値では、2つの色を比例してブレンドします。
例えば、画面の左から4分の1の所(t=0.25)では:

mix((1,0,0),(0,1,0),0.25)=(1,0,0)×0.75+(0,1,0)×0.25=(0.75,0.25,0)

赤が75%、緑が25%の、少し黄色寄りの赤です。
中央(t=0.5)では(0.5,0.5,0)で、50/50のブレンドになります。
此れにより、uColorA から uColorB への滑らかなグラデーションが作成されます。

out_color = vec4(blendedColor, 1.0); はブレンドされたRGBカラー(vec3)にアルファ値 1.0(完全に不透明)を追加して vec4 に変換します。
此れは out_color に割り当てられ、フラグメントの最終カラーとなります。

赤から緑への横方向のグラデーション

3.2 補間:色はどうやって広がるのか

頂点シェーダーが実行されるのは頂点の数だけです。
此の四角形なら4回です(インデックスでは6回参照されますが、同じ頂点の結果はGPUが再利用出来ます)。
一方、800×600の画面には48万個のピクセルが有り、フラグメントシェーダーは其の全てで実行されます。
では、4つの頂点で設定したvUvが、どうやって48万個の違う値になるのでしょうか?

答えは、頂点シェーダーとフラグメントシェーダーの間に有るラスタライザーです。
ラスタライザーはGPUの固定機能(プログラム出来ない部分)で、次の事をします:

  1. 三角形の3つの頂点のgl_Positionから、画面上の三角形を求めます。
  2. 其の三角形が覆う全てのピクセルを探します。
  3. 各ピクセルの中心について、3つの頂点への「重み」w0,w1,w2を計算します。重みは0以上で、合計は1です(重心座標と言います)。
  4. 頂点シェーダーの全てのout変数を、其の重みで混ぜた値をフラグメントシェーダーのin変数に渡します。

式にすると、此れは線型代数シリーズの第2章の線型結合其の物です:

𝐯𝐔𝐯=w0𝐮𝐯0+w1𝐮𝐯1+w2𝐮𝐯2,w0+w1+w2=1

四角形を作る2つの三角形と、三角形2の中のフラグメント。点線の数字は各頂点への重み

図の点は三角形2(頂点v2,v3,v0)の中に有ります。
重みはv0に0.5、v2に0.25、v3に0.25なので:

0.5×(0,0)+0.25×(1,1)+0.25×(0,1)=(0.25,0.5)

点の位置と同じ値になりました。
此の四角形ではUVが位置と同じ様に置かれているので、vUvは「画面のどの辺りか」を0〜1で表す値になります。
正確には、ピクセルの中心で計算されるので、左から201番目のピクセル(x = 200)では200.5/800≈0.2506になります。
従って、vUv.xが丁度0や1になるピクセルは有りません。

補間の仕方は、out/in変数の前に修飾子を付けて変える事が出来ます。

  • smooth(デフォルト):遠近法を考慮した補間。3Dで正しく見える様に、gl_Positionのwで補正します。
  • noperspective:画面上で単純に線型補間します。
  • flat:補間しません。三角形の1つの頂点(デフォルトでは最後の頂点)の値が三角形全体に使われます。フラグメントシェーダーの整数型のin変数には必須です。

此の章の四角形はw=1なので、smoothとnoperspectiveの結果は同じです。
違いが見えるのは、第13章で3Dを扱う時です。

3.3 もう一つの色を追加

3番目の色:青を追加しましょう。

先ず、main.c の2行の下に以下を追加します:

    glUniform3f(glGetUniformLocation(shaderProgram, "uColorC"), 0.0f, 0.0f, 1.0f); // 青

此れにより、フラグメントシェーダーで使用出来る新しい変数が追加されます。

fragment.glsl では、以下の宣言を追加します:

uniform vec3 uColorC;

次に、メイン関数内でtempと言うvec3を宣言し、blendedColor の値を其処に移動させ、其れをuColorC とミックスします。
2回目の補間はY軸で行いますが、青が支配的になり過ぎない様に少し抑えます。

void main() {
  vec3 temp = mix(uColorA, uColorB, vUv.x);
  vec3 blendedColor = mix(temp, uColorC, vUv.y * 0.95);
  out_color = vec4(blendedColor, 1.0);
}

macOSの場合は、同じ変更をfragment.mac.glslにも行って下さい(1行目は#version 410 coreのままです)。
ダウンロードしたfragment.mac.glslはまだ2色の版なので、Macでは此処で初めて3色になります。

1回目のmixで下の辺を赤から緑に塗り、2回目のmixで其れを上に行く程青に近づけます。
係数をvUv.y * 0.95にしているので、一番上でも青は95%で、下の色が5%残ります。
四隅と中央を計算してみましょう:

vUv temp blendedColor
(0, 0) (1, 0, 0) (1, 0, 0) 赤
(1, 0) (0, 1, 0) (0, 1, 0) 緑
(0, 1) (1, 0, 0) (0.05, 0, 0.95)
(1, 1) (0, 1, 0) (0, 0.05, 0.95)
(0.5, 0.5) (0.5, 0.5, 0) (0.2625, 0.2625, 0.475)

中央はt=0.5×0.95=0.475なので、(0.5,0.5,0)×0.525+(0,0,1)×0.475です。
スクリーンショットの中央のピクセルを調べると、8ビットで(67,67,121)、つまり0.2625×255≈67、0.475×255≈121で、計算通りです。

全て正しく行えば、結果は次の様になります:

左下が赤、右下が緑、上が青のグラデーション

次に進む前に、vUv.x、vUv.y、及び其れらに対する計算を色々試して、何が起こるかを理解して下さい。
例えばvUv.y * 0.95をvUv.y * vUv.yにすると、青が上の方にだけ集まります。

3.4 シェーダーにカラー値を移動

Cで色を定義する唯一の問題は、色を試す度にCのコードを再コンパイルする必要がある事です。
然し、uColorA、uColorB、及び uColorC をフラグメントシェーダーに移動させると、コンパイルせずに直ぐにテスト出来ます。
シェーダーのファイルは実行時に読み込まれるので、プログラムを再起動するだけで良いのです。

そこで、main.c では3行をコメントアウトします:

    // ユニフォームを設定
    //glUniform3f(glGetUniformLocation(shaderProgram, "uColorA"), 1.0f, 0.0f, 0.0f); // 赤
    //glUniform3f(glGetUniformLocation(shaderProgram, "uColorB"), 0.0f, 1.0f, 0.0f); // 緑
    //glUniform3f(glGetUniformLocation(shaderProgram, "uColorC"), 0.0f, 0.0f, 1.0f); // 青

そして、fragment.glsl では:

#version 450 core

in vec2 vUv;
out vec4 out_color;

//uniform vec3 uColorA;
//uniform vec3 uColorB;
//uniform vec3 uColorC;

void main() {
  vec3 colorA = vec3(1.0, 0.0, 0.0); // 赤
  vec3 colorB = vec3(0.0, 1.0, 0.0); // 緑
  vec3 colorC = vec3(0.0, 0.0, 1.0); // 青

  vec3 temp = mix(colorA, colorB, vUv.x);
  vec3 blendedColor = mix(temp, colorC, vUv.y * 0.95);
  out_color = vec4(blendedColor, 1.0);
}

ローカル変数にはuの付かない名前(colorA等)を使っています。
uで始まる名前はユニフォームの印なので、ユニフォームではない変数に使うと後で混乱します。

実は、C側の3行はコメントアウトしなくても動きます。
シェーダーに存在しない(又は使われていない)ユニフォームを探すと、glGetUniformLocationは−1を返し、−1へのglUniform3fは何もせずに無視されるからです。
エラーにならないのは便利ですが、ユニフォーム名を打ち間違えても何も教えてくれないと言う事でもあります。
「値を設定したのに何も変わらない」時は、先ず名前の綴りを疑って下さい。

此れで、色を変更する度にプログラムを再起動するだけで変更が確認出来ます。
Cのコンパイルは不要です!

  • Windows:Visual Studioでデバッグ実行(F5)すると、作業ディレクトリはプロジェクトのフォルダになるので、shaderフォルダのファイルが其のまま読み込まれます。シェーダーを保存してウィンドウを閉じ、もう一度F5を押すだけです。main.cは変わっていないので再コンパイルされません。x64\Debugのglsltester.exeをダブルクリックで直接起動するとshaderフォルダが見つからないので、其の場合はexeをプロジェクトのルートにコピーして其処から起動して下さい。
  • macOS:fragment.glslではなくfragment.mac.glslを編集します。Xcodeはビルドの度に(Copy Filesのビルドフェーズで).mac.glslファイルをビルド先のshaderフォルダにコピーするので、保存してCMD + Rを押せば、main.cは再コンパイルされずに新しいシェーダーで起動します。
  • Unix:build-unix.shは既にプロジェクトのルートにバイナリを出力しているので、プロジェクトのルートで./glsltesterを実行し直すだけです。ビルドスクリプトを再び実行する必要はありません。

確認の為に、色を別の物に変更してみましょう。
colorA を vec3(1.0, 0.0, 1.0)(マゼンタ)、colorB を vec3(1.0, 1.0, 0.0)(黄)、colorC を vec3(0.0, 1.0, 1.0)(シアン)に設定します:

  vec3 colorA = vec3(1.0, 0.0, 1.0); // マゼンタ
  vec3 colorB = vec3(1.0, 1.0, 0.0); // 黄
  vec3 colorC = vec3(0.0, 1.0, 1.0); // シアン

コンパイルせずにGLSLシェーダーテスターを再起動すると、次の様になります:

左下がマゼンタ、右下が黄、上がシアンのグラデーション

3.5 カラーアニメーション

最後に、もっと面白い事をします。
此れまで静的な色でしたが、時間と共に色を回転させてみましょう。

然し、問題があります。
今のシェーダーは時間を知りません。
時間を知っているのはCのプログラム(glfwGetTime())なので、色の計算はC側で行い、結果をユニフォームで渡す必要があります。
其処で、前の節の変更を元に戻します。
(第5章では、時間其の物をユニフォームとして渡し、シェーダーの中でアニメーションする方法を作ります。)

fragment.glsl では:

#version 450 core

in vec2 vUv;
out vec4 out_color;

uniform vec3 uColorA;
uniform vec3 uColorB;
uniform vec3 uColorC;

void main() {
  vec3 temp = mix(uColorA, uColorB, vUv.x);
  vec3 blendedColor = mix(temp, uColorC, vUv.y * 0.95);
  out_color = vec4(blendedColor, 1.0);
}

そして、main.c では、3行のコメントを解除します:

    // ユニフォームを設定
    glUniform3f(glGetUniformLocation(shaderProgram, "uColorA"), 1.0f, 0.0f, 0.0f); // 赤
    glUniform3f(glGetUniformLocation(shaderProgram, "uColorB"), 0.0f, 1.0f, 0.0f); // 緑
    glUniform3f(glGetUniformLocation(shaderProgram, "uColorC"), 0.0f, 0.0f, 1.0f); // 青

色の値を9つのバラバラなfloatで扱うのは見にくいので、プロジェクトのincludeディレクトリに有るvector.hを使います。
此のヘッダーはVector2、Vector3、Vector4と言う小さな型を定義しています。
共用体(union)になっているので、同じ値をv.x、v.y、v.zともv.r、v.g、v.bとも呼べます。GLSLのスウィズルと同じ考え方です。

typedef union {
  struct {
    float x;
    float y;
    float z;
  };
  struct {
    float r;
    float g;
    float b;
  };
} Vector3;

main.c に vector.h 及び math.h ヘッダーを追加し、whileループのユニフォームの部分を以下の様に修正します:

#include <vector.h>
#include <math.h>
...
    // 時間に基づいて色をアニメーション
    float time = (float)glfwGetTime();
    float speed = 1.0f; // アニメーションの速度
    float phase = 2.0f * 3.14159f / 3.0f; // 120度の位相差(3色用)

    // uColorA: 赤 -> 緑 -> 青
    Vector3 colorA;
    colorA.r = sin(time * speed + 0.0f) * 0.5f + 0.5f; // 0.0 to 1.0
    colorA.g = sin(time * speed + phase) * 0.5f + 0.5f;
    colorA.b = sin(time * speed + 2.0f * phase) * 0.5f + 0.5f;

    // uColorB: 緑 -> 青 -> 赤
    Vector3 colorB;
    colorB.r = sin(time * speed + 2.0f * phase) * 0.5f + 0.5f;
    colorB.g = sin(time * speed + 0.0f) * 0.5f + 0.5f;
    colorB.b = sin(time * speed + phase) * 0.5f + 0.5f;

    // uColorC: 青 -> 赤 -> 緑
    Vector3 colorC;
    colorC.r = sin(time * speed + phase) * 0.5f + 0.5f;
    colorC.g = sin(time * speed + 2.0f * phase) * 0.5f + 0.5f;
    colorC.b = sin(time * speed + 0.0f) * 0.5f + 0.5f;

    // ユニフォームを設定
    glUniform3f(glGetUniformLocation(shaderProgram, "uColorA"), colorA.r, colorA.g, colorA.b);
    glUniform3f(glGetUniformLocation(shaderProgram, "uColorB"), colorB.r, colorB.g, colorB.b);
    glUniform3f(glGetUniformLocation(shaderProgram, "uColorC"), colorC.r, colorC.g, colorC.b);

glfwGetTime()はGLFWを初期化してからの秒数を返します。
各チャンネルは同じ形の式で計算されています:

c(t)=0.5+0.5sin(st+φ)

sはspeed、φ(ファイ)は位相(波をずらす量)です。
sinは−1〜1の間を往復するので、0.5を掛けて0.5を足すと0〜1の範囲になり、其のまま色として使えます。
位相は0、2π3(120°)、4π3(240°)の3つで、R、G、Bの波が丁度3分の1周期ずつずれます。
其の為、赤が一番明るい時、緑と青は其れより暗く、時間と共に「赤→緑→青」と明るいチャンネルが入れ替わります。
3つの色は同じ値を並べ替えた物なので、3つの角は常に違う色になります。

t=0でcolorAを計算してみましょう:

r=0.5+0.5sin0=0.5g=0.5+0.5sin2π3=0.5+0.5×0.866=0.933b=0.5+0.5sin4π3=0.5−0.5×0.866=0.067

120°ずつずれた3つのサインの合計は常に0なので、r+g+bはいつでも1.5です。
明るさが大体一定のまま色合いだけが回るのは此の為です。

Unixの場合、sinは数学ライブラリに有るので、リンク時に-lmが必要です(build-unix.shには既に入っています)。

さて、値を使って試してみる宿題を出します。
speed、phase、0.5fを変えて、其々が何をするのか理解して下さい。

最終的な結果は次の様になります(5秒間の録画):

2秒後のアニメーションの1コマ

3.6 其の他のグラデーションの形

此処までのグラデーションは全てvUv.xかvUv.yをそのままmixの係数にしていました。
係数tの作り方を変えるだけで、グラデーションの形は自由に変えられます。
此の節のシェーダーはfragment.glslを丸ごと置き換えて試して下さい(ユニフォームは使わないので、C側は其のままで構いません)。

斜めのグラデーション

左下から右上へのグラデーションは、xとyの平均を係数にするだけです:

#version 450 core

in vec2 vUv;
out vec4 out_color;

void main() {
  vec3 colorA = vec3(0.1, 0.1, 0.4); // 紺
  vec3 colorB = vec3(1.0, 0.6, 0.2); // オレンジ

  // 左下が0、右上が1
  float t = (vUv.x + vUv.y) * 0.5;
  out_color = vec4(mix(colorA, colorB, t), 1.0);
}

好きな角度のグラデーションにするには、線型代数シリーズの第4章の内積を使います。
単位ベクトル𝐝^との内積は「其の方向にどれだけ進んでいるか」を表すので、画面の中心からの其の値をそのまま係数にします:

t=(𝐮𝐯−(0.5,0.5))⋅𝐝^+0.5,𝐝^=(cosθ,sinθ)

#version 450 core

in vec2 vUv;
out vec4 out_color;

void main() {
  vec3 colorA = vec3(0.1, 0.1, 0.4); // 紺
  vec3 colorB = vec3(1.0, 0.6, 0.2); // オレンジ

  float angle = radians(30.0);              // グラデーションの向き
  vec2 dir = vec2(cos(angle), sin(angle));  // 長さ1の方向ベクトル
  float t = dot(vUv - 0.5, dir) + 0.5;      // 中心からの、dir方向の距離
  t = clamp(t, 0.0, 1.0);
  out_color = vec4(mix(colorA, colorB, t), 1.0);
}

vUv - 0.5の様にvec2からfloatを引くと、全ての成分から引かれます。
radiansは度をラジアンに変換します(度×π/180)。

clamp(t, 0.0, 1.0)はtを0〜1の範囲に収めます。
何故必要なのでしょうか?
30°の場合、右上の角では(0.5,0.5)⋅(0.866,0.5)+0.5=1.183になり、1を超えます。
mixはtを制限しないので、t=1.183では𝐚+1.183(𝐛−𝐚)=(1.165,0.692,0.163)と、オレンジを「通り過ぎた」色になります。
画面に書き込まれる時に1を超えた分は切り捨てられますが、意図した色ではありません。
グラデーションの両端の色で止めたいなら、clampで係数を制限するのが基本です。

左:(x + y) / 2の斜めのグラデーション。右:30度のグラデーション

円形のグラデーション

中心からの距離を係数にすると、円形(放射状)のグラデーションになります。
距離は線型代数シリーズの第3章のベクトルの長さで、GLSLではlengthです:

length(𝐩)=‖𝐩‖=px2+py2

#version 450 core

in vec2 vUv;
out vec4 out_color;

void main() {
  vec3 inner = vec3(1.0, 0.9, 0.5); // 中心の色
  vec3 outer = vec3(0.2, 0.0, 0.3); // 外側の色

  vec2 p = vUv - 0.5;          // 中心を(0, 0)にする
  p.x *= 800.0 / 600.0;        // 横長の画面でも円になる様に
  float t = length(p) * 2.0;   // 中心で0、上下の端で1
  t = clamp(t, 0.0, 1.0);
  out_color = vec4(mix(inner, outer, t), 1.0);
}

p.x *= 800.0 / 600.0;の行が無いと、円ではなく楕円になります。
UVは横も縦も0〜1ですが、画面は横800ピクセル、縦600ピクセルなので、UVの0.1は横では80ピクセル、縦では60ピクセルだからです。
xに画面の縦横比(アスペクト比)800/600≈1.333を掛けると、xとyの単位が揃います。
此処では数字を直接書きましたが、ウィンドウの大きさが変わると合わなくなります。
第5章では、画面の大きさをユニフォームで受け取って此れを正しく直します。

数字で確かめましょう。
画面の中心では𝐩=(0,0)なのでt=0です。
上の端の中央では𝐩=(0,0.5)なのでt=0.5×2=1です。
右の端の中央では𝐩=(0.5×1.333,0)=(0.667,0)なのでt=1.333になり、clampで1になります。

左:アスペクト比を直さない楕円。右:直した円

smoothstepで滑らかに

線型のグラデーションは、始まりと終わりで急に変化が止まるので、端に薄い「折れ目」が見える事があります。
smoothstepは、始まりと終わりの傾きが0になるS字カーブで、此れを解決します:

smoothstep(e0,e1,x)=t2(3−2t),t=clamp(x−e0e1−e0,0,1)

xがe0以下なら0、e1以上なら1、其の間は滑らかに0から1に変わります。
例えばsmoothstep(0,1,0.25)はt=0.25なので、0.0625×2.5=0.15625です。
線型なら0.25の所で、まだ0.156しか進んでいません。
真ん中のx=0.5では0.25×2=0.5で、線型と同じです。

線型とsmoothstepのグラフ。smoothstepは両端で平らになる

画面の上半分を線型、下半分をsmoothstepにして比べてみましょう:

#version 450 core

in vec2 vUv;
out vec4 out_color;

void main() {
  vec3 colorA = vec3(0.1, 0.1, 0.4); // 紺
  vec3 colorB = vec3(1.0, 0.6, 0.2); // オレンジ

  float t;
  if (vUv.y > 0.5) {
    t = vUv.x;                         // 上半分:線型
  } else {
    t = smoothstep(0.0, 1.0, vUv.x);   // 下半分:smoothstep
  }
  vec3 color = mix(colorA, colorB, t);

  // 境目に細い線を引く
  if (abs(vUv.y - 0.5) < 0.002) color = vec3(1.0);
  out_color = vec4(color, 1.0);
}

absは絶対値です。
abs(vUv.y - 0.5) < 0.002は「vUv.yが0.5から0.002以内」と言う意味で、画面の真ん中に高さ2〜3ピクセルの線を引きます。

上半分が線型、下半分がsmoothstepのグラデーション

下半分では、左右の端の色が広く残り、中央で素早く変わっています。
smoothstepのe0とe1を近づけると(例:smoothstep(0.45, 0.55, vUv.x))、殆ど境界線の様な鋭いグラデーションになります。
此の性質は、第6章で図形の縁を滑らかにする(アンチエイリアス)時に大活躍します。

複数の色を繋げる

mixを重ねれば、色は幾つでも繋げられます。
地面・地平線・空の3色で夕焼けを作ってみましょう:

#version 450 core

in vec2 vUv;
out vec4 out_color;

void main() {
  vec3 ground  = vec3(0.05, 0.04, 0.08);
  vec3 horizon = vec3(1.0, 0.55, 0.25);
  vec3 sky     = vec3(0.15, 0.2, 0.5);

  vec3 color = mix(ground, horizon, smoothstep(0.25, 0.32, vUv.y));
  color = mix(color, sky, smoothstep(0.32, 0.9, vUv.y));
  out_color = vec4(color, 1.0);
}

1回目のmixはvUv.yが0.25〜0.32の狭い範囲で地面から地平線の色に切り替わり、2回目のmixは0.32〜0.9の広い範囲で空の色に変わります。
smoothstepの範囲を狭くすると境目がくっきりし、広くするとぼんやりします。

地面、オレンジの地平線、青い空の夕焼けのグラデーション

3.7 此の章で使ったGLSLの機能

  • mix(a, b, t):a(1−t)+bt。線型補間です。ベクトルには成分毎に働き、tを制限しません。
  • clamp(x, lo, hi):min(max(x,lo),hi)。値を範囲内に収めます。
  • smoothstep(e0, e1, x):t2(3−2t)、tはxをe0〜e1から0〜1に変換してclampした値です。
  • length(v):ベクトルの長さx2+y2(3次元ならz2も足します)。
  • dot(a, b):内積axbx+ayby。単位ベクトルとの内積は、其の方向の成分です。
  • sin(x)、cos(x):ラジアンで角度を受け取ります。radians(deg)は度をラジアンに変換します。
  • abs(x):絶対値。
  • in/out:ステージ間で値を渡します。名前と型が一致しなければなりません。
  • smooth/noperspective/flat:補間の仕方を変える修飾子です。
  • uniform:CからglUniform*で設定する、描画中は一定の値です。存在しないユニフォームへの設定は黙って無視されます。

3.8 ゲームやエンジンでの使い方

グラデーションと補間は、ゲームの画面の殆どの場所に隠れています。

  • 空:多くのゲームは、空を上下2色か3色のグラデーションで描いています。カメラの向きのy成分を係数にすれば、見上げると空の色、見下ろすと地平線の色になります。
  • 霧(フォグ):カメラからの距離を係数にして、物体の色を霧の色にmixします。遠くの物が段々空気に溶けていく、昔からある手法です。
  • 頂点カラー:PlayStation時代のゲームでは、テクスチャの代わりに頂点に色を持たせ、ラスタライザーの補間で面を塗る事がよく有りました。今でも地形のブレンドや草の揺れの強さ等、色以外のデータを頂点に入れて補間させます。
  • UI:ボタン、体力ゲージ、テキストの影等。ゲージの「残り量」はstepやsmoothstepで作るのが定番です。
  • 画面効果:フェードイン・フェードアウトは「画面の色を黒に向かってmixする」だけです。ダメージを受けた時の赤いフラッシュも同じです。
  • 時間で動く値:此の章のサインの式は、点滅するアイテム、呼吸するように光るUI、水面の揺れ等、ゲームのあらゆる「ゆらゆら」に使われます。

3.9 まとめ

  • 頂点シェーダーは頂点毎、フラグメントシェーダーはピクセル毎に実行されます。
  • ラスタライザーは頂点シェーダーのout変数を重心座標の重みで補間し、フラグメントシェーダーのin変数に渡します。
  • mix(a, b, t)はa(1−t)+btで、線型代数のlerpと同じです。
  • 係数tの作り方を変えると、横・縦・斜め(dot)・円形(length)等のグラデーションが作れます。
  • mixはtを制限しないので、範囲外になり得る時はclampします。
  • smoothstepは両端で傾きが0のS字カーブで、滑らかな切り替えに使います。
  • シェーダーは実行時に読み込まれるので、シェーダーだけの変更はCの再コンパイル無しで試せます。
  • 時間で変わる値はC側で計算してユニフォームで渡せます(第5章では時間其の物を渡します)。

3.10 課題

  1. ★ 2色のシェーダー(赤→緑)で、vUv.x = 0.75のピクセルの色を手で計算して下さい。次に、3色のシェーダーでvUv = (0.5, 0)とvUv = (0.5, 1)の色を計算して下さい。
  2. ★ smoothstep(0.0, 1.0, 0.75)とsmoothstep(2.0, 4.0, 3.0)を手で計算して下さい(ヒント:2つ目は先ずtを求めます)。
  3. ★★ グラデーションを縦にして下さい。下が赤、上が緑になり、横方向には色が変わらない筈です。
  4. ★★ 四隅に別々の色(例:左下が赤、右下が緑、左上が青、右上が白)を置くシェーダーを書いて下さい(ヒント:下の辺と上の辺を其々mixし、其の2つをvUv.yでmixします)。四隅が其の色ピッタリになり、中央は4色の平均(0.5,0.5,0.5)の灰色になる筈です。
  5. ★★ 円形のグラデーションを「輪」にして下さい。中心からの距離が0.3の所だけが明るく、其処から離れると暗くなる様にします(ヒント:abs(length(p) - 0.3))。
  6. ★★ main.cでphaseを0.0fにすると何が起きるか予想してから試して下さい。全てのチャンネルが同じ値になるので、画面全体が灰色のまま黒と白の間で明滅する筈です。
  7. ★★★ 赤と緑のmixの中央(0.5,0.5,0)は、少し暗く濁った黄色に見えます。其の理由を調べて下さい(キーワード:sRGB、ガンマ)。そして、pow(color, vec3(2.2))で色を「線型の空間」に変換してからmixし、pow(result, vec3(1.0 / 2.2))で戻すと、中央がどう変わるか比べて下さい。ガンマについては第10章で詳しく説明します。

DIFFをダウンロード

ファイル: a/main.c | b/main.c

前新
@@ -9,6 +9,8 @@
9 #include <GLFW/glfw3.h> 9 #include <GLFW/glfw3.h>
10 #include <stdio.h> 10 #include <stdio.h>
11 #include <stdlib.h> 11 #include <stdlib.h>
    12 #include <vector.h>
    13 #include <math.h>
12   14  
13 // ファイルパスを構築(プラットフォームに応じて) 15 // ファイルパスを構築(プラットフォームに応じて)
14 char *constructFilePath(const char *basePath) { 16 char *constructFilePath(const char *basePath) {
@@ -229,9 +231,33 @@ int main(int argc, char **argv) {
229 // シェーダープログラムを使用 231 // シェーダープログラムを使用
230 glUseProgram(shaderProgram); 232 glUseProgram(shaderProgram);
231   233  
    234 // 時間に基づいて色をアニメーション
    235 float time = (float)glfwGetTime();
    236 float speed = 1.0f; // アニメーションの速度
    237 float phase = 2.0f * 3.14159f / 3.0f; // // 120度の位相差(3色用)
    238  
    239 // uColorA: 赤 -> 緑 -> 青
    240 Vector3 colorA;
    241 colorA.r = sin(time * speed + 0.0f) * 0.5f + 0.5f; // 0.0 to 1.0
    242 colorA.g = sin(time * speed + phase) * 0.5f + 0.5f;
    243 colorA.b = sin(time * speed + 2.0f * phase) * 0.5f + 0.5f;
    244  
    245 // uColorB: 緑 -> 青 -> 赤
    246 Vector3 colorB;
    247 colorB.r = sin(time * speed + 2.0f * phase) * 0.5f + 0.5f;
    248 colorB.g = sin(time * speed + 0.0f) * 0.5f + 0.5f;
    249 colorB.b = sin(time * speed + phase) * 0.5f + 0.5f;
    250  
    251 // uColorC: 青 -> 赤 -> 緑
    252 Vector3 colorC;
    253 colorC.r = sin(time * speed + phase) * 0.5f + 0.5f;
    254 colorC.g = sin(time * speed + 2.0f * phase) * 0.5f + 0.5f;
    255 colorC.b = sin(time * speed + 0.0f) * 0.5f + 0.5f;
    256  
232 // ユニフォームを設定 257 // ユニフォームを設定
233 glUniform3f(glGetUniformLocation(shaderProgram, "uColorA"), 1.0f, 0.0f, 0.0f); // 赤 258 glUniform3f(glGetUniformLocation(shaderProgram, "uColorA"), colorA.r, colorA.g, colorA.b); // 赤
234 glUniform3f(glGetUniformLocation(shaderProgram, "uColorB"), 0.0f, 1.0f, 0.0f); // 緑 259 glUniform3f(glGetUniformLocation(shaderProgram, "uColorB"), colorB.r, colorB.g, colorB.b); // 緑
    260 glUniform3f(glGetUniformLocation(shaderProgram, "uColorC"), colorC.r, colorC.g, colorC.b); // 青
235   261  
236 // クアッドを描画 262 // クアッドを描画
237 glBindVertexArray(VAO); 263 glBindVertexArray(VAO);

ファイル: a/shader/fragment.glsl | b/shader/fragment.glsl

前新
@@ -5,8 +5,10 @@ out vec4 out_color;
5   5  
6 uniform vec3 uColorA; 6 uniform vec3 uColorA;
7 uniform vec3 uColorB; 7 uniform vec3 uColorB;
    8 uniform vec3 uColorC;
8   9  
9 void main() { 10 void main() {
10 vec3 blendedColor = mix(uColorA, uColorB, vUv.x); 11 vec3 temp = mix(uColorA, uColorB, vUv.x);
    12 vec3 blendedColor = mix(temp, uColorC, vUv.y * 0.95);
11 out_color = vec4(blendedColor, 1.0); 13 out_color = vec4(blendedColor, 1.0);
12 } 14 }

ファイル: a/shader/fragment.mac.glsl | b/shader/fragment.mac.glsl

前新
@@ -5,8 +5,10 @@ out vec4 out_color;
5   5  
6 uniform vec3 uColorA; 6 uniform vec3 uColorA;
7 uniform vec3 uColorB; 7 uniform vec3 uColorB;
    8 uniform vec3 uColorC;
8   9  
9 void main() { 10 void main() {
10 vec3 blendedColor = mix(uColorA, uColorB, vUv.x); 11 vec3 temp = mix(uColorA, uColorB, vUv.x);
    12 vec3 blendedColor = mix(temp, uColorC, vUv.y * 0.95);
11 out_color = vec4(blendedColor, 1.0); 13 out_color = vec4(blendedColor, 1.0);
12 } 14 }


コメント(0)

まだコメントはありません。